Fresnel Equations

ll[llist_]:=Grid[{Graphics[{#[[1]],Line[{{0,0},{1,0}}]},AspectRatio->.1,ImageSize->25],#[[2]]}&/@llist,Alignment->{Left,Center}]

nlegend[llist_]:=Panel[Grid[{Map[ll,llist,{1}]}],BaseStyle->{FontFamily->"Times",Italic,14}]

rperp[ni_,nt_,θi_,θt_]:=((ni Cos[θi]-nt Cos[θt])/(ni Cos[θi]+nt Cos[θt]))

tperp[ni_,nt_,θi_,θt_]:=((2ni Cos[θi])/(ni Cos[θi]+nt Cos[θt]))

rpara[ni_,nt_,θi_,θt_]:=((nt Cos[θi]-ni Cos[θt])/(ni Cos[θt]+nt Cos[θi]))

tpara[ni_,nt_,θi_,θt_]:=((2ni Cos[θi])/(ni Cos[θt]+nt Cos[θi]))

θt[ni_,nt_,θi_]:=ArcSin[ni Sin[θi]/nt]

Rperp[ni_,nt_,θi_,θt_]:=((Abs[rperp[ni,nt,θi,θt]])^2)

Tperp[ni_,nt_,θi_,θt_]:=((Abs[tperp[ni,nt,θi,θt]])^(2 ))((nt Cos[θt])/(ni Cos[θi]))

Rpara[ni_,nt_,θi_,θt_]:=((Abs[rpara[ni,nt,θi,θt]])^2)

Tpara[ni_,nt_,θi_,θt_]:=((Abs[tpara[ni,nt,θi,θt]])^(2 ))((nt Cos[θt])/(ni Cos[θi]))

Manipulate[Module[{rped,rpad,tped,tpad,brad,tird,θB,θrtot,g,l},
rped=Directive[Thick,Dashed,Blue];
rpad=Directive[Thick,Dashed,Red];
tped=Directive[Thick,Blue];
tpad=Directive[Thick,Red];
brad=Directive[Thick,Dashed,Green];
tird=Directive[Black,Opacity[0.25],Thickness[0.5]];
θB=ArcTan[nt/ni];
θrtot=If[ni>nt,ArcSin[nt/ni],0];
{g,l}=Which[
plot=="power ratios",
	{
	Plot[{Rperp[ni,nt,θi Degree,θt[ni,nt,θi Degree]],
		Rpara[ni,nt,θi Degree,θt[ni,nt,θi Degree]],
		If[ni>nt&&θi>θrtot/Degree,0,Tperp[ni,nt,θi Degree,θt[ni,nt,θi Degree]]],
		If[ni>nt&&θi>θrtot/Degree,0,Tpara[ni,nt,θi Degree,θt[ni,nt,θi Degree]]]},{θi,0,90},
		PlotStyle->{rped,rpad,tped,tpad},
		Frame->True,FrameLabel->{"angle of incidence (Subscript[θ, i]) (deg)","transmission / reflection","power ratios"},
		GridLinesStyle->LightGray ,GridLines->{Range[0,90,10],Range[-1,1,0.1]},
		PlotRange->{{0,90},{0,1}},
		Prolog->{If[θrtot>0,{tird,Rectangle[{θrtot/Degree,0},{90,1}]},{}],
		brad,Line[{{θB/Degree,0},{θB/Degree,1}}],
		Black,Rotate[Text["Brewster's angle",{θB/Degree-2.5,0.5}],π/2]}],
	nlegend[{{{tped,"\!\(\*SubscriptBox[\(T\), \(\(⊥\)\(\\ \)\)]\)= (Subscript[P, r⊥])/(Subscript[P, i⊥])"},{tpad,"(Subscript[T, ∥]) = (Subscript[P, r∥])/(Subscript[P, i∥])"}},{},
		{{rped,"(Subscript[R, ⊥]) = (Subscript[P, r⊥])/(Subscript[P, i⊥])"},{rpad,"(Subscript[R, ∥]) = (Subscript[P, r∥])/(Subscript[P, i∥])"}},{},
		{{brad,"Brewster's angle"},{tird,"total internal reflection"}}}]
	},
plot=="amplitude ratios",
	{
	Plot[{Abs@rperp[ni,nt,θi Degree,θt[ni,nt,θi Degree]],
		Abs@rpara[ni,nt,θi Degree,θt[ni,nt,θi Degree]],
		Abs@tperp[ni,nt,θi Degree,θt[ni,nt,θi Degree]],
		Abs@tpara[ni,nt,θi Degree,θt[ni,nt,θi Degree]]},{θi,0,90},
		PlotStyle->{rped,rpad,tped,tpad},
		Frame->True,FrameLabel->{"angle of incidence (Subscript[θ, i]) (deg)","transmission / reflection",Row[{Style["E",Italic]," field ratios"}]},
		GridLinesStyle->LightGray ,GridLines->{Range[0,90,10],Range[0,2,0.5]},
		PlotRange->{{0,90},{0,2}},
		Prolog->{If[θrtot>0,{tird,Rectangle[{θrtot/Degree,0},{90,3}]},{}],
		brad,Line[{{θB/Degree,0},{θB/Degree,2}}],
		Black,Rotate[Text["Brewster's angle",{θB/Degree-2.5,1}],π/2]}],
	nlegend[{{{tped,"|(Subscript[t, ⊥])| = |(Subscript[E, t⊥])/(Subscript[E, i⊥])|"},{tpad,"|(Subscript[t, ∥])| = |(Subscript[E, t∥])/(Subscript[E, i∥])|"}},{},
		{{rped,"|(Subscript[r, ⊥])| = |(Subscript[E, r⊥])/(Subscript[E, i⊥])|"},{rpad,"|(Subscript[r, ∥])| = |(Subscript[E, r∥])/(Subscript[E, i∥])|"}},{},
		{{brad,"Brewster's angle"},{tird,"total internal reflection"}}}]
	},
plot=="dephasings",
	{
	Plot[{Arg@Chop@rperp[ni,nt,θi Degree,θt[ni,nt,θi Degree]]/Degree,
		Arg@Chop@rpara[ni,nt,θi Degree,θt[ni,nt,θi Degree]]/Degree,
		Arg@Chop@tperp[ni,nt,θi Degree,θt[ni,nt,θi Degree]]/Degree,
		Arg@Chop@tpara[ni,nt,θi Degree,θt[ni,nt,θi Degree]]/Degree},{θi,0,90},
		PlotStyle->{rped,rpad,tped,tpad},
		Frame->True,FrameLabel->{"angle of incidence (Subscript[θ, i]) (deg)","dephasing (deg)","dephasings"},
		GridLinesStyle->LightGray ,GridLines->{Range[0,90,10],180 Range[-1,1,0.25]},
		PlotRange->{{0,90},{-180,180}},PlotRangePadding->{None,10},
		FrameTicks->{Automatic,{-180,-90,0,90,180},None,None},
		Prolog->{If[θrtot>0,{tird,Rectangle[{θrtot/Degree,-190},{90,190}]},{}],
		brad,Line[{{θB/Degree,-180},{θB/Degree,180}}],
		Black,Rotate[Text["Brewster's angle",{θB/Degree-2.5,0}],π/2]}],
	nlegend[{{{tped,"arg((Subscript[E, t⊥])/(Subscript[E, i⊥]))"},{tpad,"arg((Subscript[E, t∥])/(Subscript[E, i∥]))"}},{},
		{{rped,"arg((Subscript[E, r⊥])/(Subscript[E, i⊥]))"},{rpad,"arg((Subscript[E, r∥])/(Subscript[E, i∥]))"}},{},
		{{brad,"Brewster's angle"},{tird,"total internal reflection"}}}]
	}
];
Grid[{
{Pane[Show[g,BaseStyle->{16},ImagePadding->{{70,50},{50,30}},ImageSize->500],{590,350},Alignment->{Center,Center}]},{l}
}]
],
{{plot,"power ratios","display"},{"amplitude ratios","dephasings","power ratios"},ControlType->RadioButton},
{{ni,1.0,"refractive index (Subscript[n, i])"},1,2,Appearance->{Small,"Labeled"}},
{{nt,1.5,"refractive index (Subscript[n, t])"},1,2,Appearance->"Labeled"},
SaveDefinitions->True]

CAPTION

Fresnel equations describe how light is transmitted and reflected when crossing the interface between two dielectric media of differing indices of refraction. This Demonstration shows how the transmission and reflection coefficients both depend on the angle of incidence (Subscript[θ, i]) between the light beam and the normal to the interface and on the light polarization, which can be either parallel (∥) or perpendicular (⊥) to the plane of incidence. You can display either the electric field amplitude ratios and their dephasings, or the power ratios. You can change the refractive indices of the first ((Subscript[n, i])) or second ((Subscript[n, t])) medium and observe how the coefficients change. When (Subscript[n, i])<(Subscript[n, t]), reflection increases at large angles and tends to 1 for 90°. When (Subscript[n, i])>(Subscript[n, t]), you observe total internal reflection when the angle of incidence is bigger than the critical angle (Subscript[θ, c]). In this case, all the power is reflected and the transmitted field is an evanescent wave (instead of a traveling wave). Another angle of interest is Brewster's angle (Subscript[θ, B]), for which light with parallel polarization is fully transmitted; thus reflected light will be polarized perpendicularly to the plane of incidence whatever the polarization of incoming light.

DETAILS

Fresnel equations for the transmission and reflection of light with parallel polarization are given by [1]:

(Subscript[t, ∥])=((Subscript[E, t∥])/(Subscript[E, i∥]))=((2(Subscript[n, i]) cos((Subscript[θ, i])))/((Subscript[n, i]) cos((Subscript[θ, t])) + (Subscript[n, t]) cos((Subscript[θ, i]))))   and   (Subscript[r, ∥])=((Subscript[E, r∥])/(Subscript[E, i∥]))=(((Subscript[n, t])cos((Subscript[θ, i])) - (Subscript[n, i]) cos((Subscript[θ, t])))/((Subscript[n, i]) cos((Subscript[θ, t])) + (Subscript[n, t]) cos((Subscript[θ, i]))))

and for light with perpendicular polarization,

(Subscript[t, ⊥])=((Subscript[E, t⊥])/(Subscript[E, i⊥]))=((2(Subscript[n, i]) cos((Subscript[θ, i])))/((Subscript[n, i]) cos((Subscript[θ, i])) + (Subscript[n, t])cos((Subscript[θ, t]))))  and   (Subscript[r, ⊥])=((Subscript[E, r⊥])/(Subscript[E, i⊥]))=(((Subscript[n, i]) cos((Subscript[θ, i])) - (Subscript[n, t]) cos((Subscript[θ, t])))/((Subscript[n, i]) cos((Subscript[θ, i])) + (Subscript[n, t])cos((Subscript[θ, t])))).

In these equations (Subscript[E, t]), (Subscript[E, r]), and (Subscript[E, i]) refer to the electric fields of the transmitted, reflected, and incident light beams. (Subscript[n, i]) and (Subscript[n, t]) are the refractive indices of the first and second media. The angle of the transmitted beam (Subscript[θ, t]) is related to the angle of incidence (Subscript[θ, i]) by Snell's law:

(Subscript[n, t]) sin((Subscript[θ, t]))=(Subscript[n, i]) sin((Subscript[θ, i])).

In general, these electric field ratios are complex numbers and the transmission and reflection coefficients displayed here are the absolute values of these ratios:

|(Subscript[t, ∥])|=|((Subscript[E, t∥])/(Subscript[E, i∥]))|, |(Subscript[t, ⊥])|=|((Subscript[E, t⊥])/(Subscript[E, i⊥]))|, |(Subscript[r, ∥])|=|((Subscript[E, r∥])/(Subscript[E, i∥]))|, |(Subscript[r, ⊥])|=|((Subscript[E, r⊥])/(Subscript[E, i⊥]))|

with the respective dephasings:

arg(((Subscript[E, t∥])/(Subscript[E, i∥]))),  arg(((Subscript[E, t⊥])/(Subscript[E, i⊥]))),  arg(((Subscript[E, r∥])/(Subscript[E, i∥]))),  arg(((Subscript[E, r⊥])/(Subscript[E, i⊥]))).

You obtain the power reflection coefficients by squaring the electric field ratios:

(Subscript[R, ∥])=((|((Subscript[E, r∥])/(Subscript[E, i∥]))|)^2), (Subscript[R, ⊥])=((|((Subscript[E, r⊥])/(Subscript[E, i⊥]))|)^2).

For the power transmission coefficients, a factor (Subscript[n, t])/(Subscript[n, i]) is needed to account for the change of medium and a factor cos((Subscript[θ, t]))/cos((Subscript[θ, i])) for the change of surface area related to the change of direction of the transmitted beam. Therefore, you obtain:

(Subscript[T, ∥])=(((Subscript[n, t ])cos((Subscript[θ, t])))/((Subscript[n, i])cos((Subscript[θ, i]))))((|((Subscript[E, t∥])/(Subscript[E, i∥]))|)^2), (Subscript[T, ⊥])=(((Subscript[n, t ])cos((Subscript[θ, t])))/((Subscript[n, i])cos((Subscript[θ, i]))))((|((Subscript[E, t⊥])/(Subscript[E, i⊥]))|)^2).

You can check that they satisfy energy conservation:

(Subscript[T, ∥])+(Subscript[R, ∥])=1 and (Subscript[T, ⊥])+(Subscript[R, ⊥])=1.

Note that in the case of total internal reflection, the transmitted electric field amplitude is different from zero, but it corresponds to an evanescent wave (not a traveling wave) and as a consequence the transmitted intensity and power are both equal to zero.

Reference:

[1]  E. Hecht, Optics, 4th ed., Reading, MA: Addison–Wesley, 2002.

THIS NOTEBOOK IS THE SOURCE CODE FROM

"Fresnel Equations" from the Wolfram Demonstrations Project
 http://demonstrations.wolfram.com/FresnelEquations/

Contributed by: Gianni Di Domenico (Université de Neuchâtel)

A full-function Wolfram Mathematica system (Version 6 or higher) is required to edit this notebook.
GET WOLFRAM MATHEMATICA »

© Wolfram Demonstrations Project & Contributors   |   Terms of Use   |   Make a new version of this Demonstration »