Complex Spherical Harmonics

lab1={Text[Style["x",Italic]],Text[Style["y",Italic]],Text[Style["z",Italic]]};

Manipulate[
If[m>L,m=L];
If[m<-L,m=-L];
GraphicsRow[{SphericalPlot3D[Abs[SphericalHarmonicY[L,m,ϑ,ϕ]],{ϑ,0,Pi},{ϕ,-Pi,Pi},ColorFunction->Function[{x,y,z,t,p,r},Hue[Arg[SphericalHarmonicY[L,m,t,p]]/(2. Pi)]],ColorFunctionScaling->False,PerformanceGoal->"Quality",Axes->True,TicksStyle->Directive[Gray],AxesLabel->lab1,SphericalRegion->True,Mesh->False,Boxed->True,PlotLabel->Style[With[{L=L,m=Round@m},TraditionalForm[HoldForm[SphericalHarmonicY[L,m,"θ","ϕ"]]]  ],14],PlotRange->All],

SphericalPlot3D[Abs[Re[SphericalHarmonicY[L,m,ϑ,ϕ]]],{ϑ,0,Pi},{ϕ,-Pi,Pi},ColorFunction->Function[{x,y,z,t,p,r},Hue[Arg[Re[SphericalHarmonicY[L,m,t,p]]]/(2. Pi)]],ColorFunctionScaling->False,PerformanceGoal->"Quality",Axes->True,TicksStyle->Directive[Gray],
AxesLabel->lab1,Boxed->True,BoxStyle->Directive[Lighter[Gray]],Mesh->False,PlotLabel-> Style[With[{L=L,m=Round@m},Row[{"Re ",TraditionalForm[HoldForm[SphericalHarmonicY[L,m,"θ","ϕ"]]] }] ],14],PlotRange->All],

SphericalPlot3D[Abs[Im[SphericalHarmonicY[L,m,ϑ,ϕ]]],{ϑ,0,Pi},{ϕ,-Pi,Pi},ColorFunction->Function[{x,y,z,t,p,r},Hue[Arg[Im[SphericalHarmonicY[L,m,t,p]]]/(2. Pi)]],ColorFunctionScaling->False,PerformanceGoal->"Quality",Axes->True,TicksStyle->Directive[Gray],Boxed->True,BoxStyle->Directive[Lighter[Gray]],
Mesh->False,AxesLabel->lab1,PlotLabel->Style[With[{L=L,m=Round@m},Row[{"Im ",TraditionalForm[HoldForm[SphericalHarmonicY[L,m,"θ","ϕ"]]] }] ],14],PlotRange->All]},ImageSize->600],

{{L,0,Style["l",Italic]},0,4,1},
{{m,0,Style["m",Italic]},Range[-L,L]},
TrackedSymbols:>{L,m},ControlType->SetterBar,SaveDefinitions->True]

CAPTION

Spherical harmonic functions arise for central force problems in quantum mechanics as the angular part of the Schrödinger equation in spherical polar coordinates. They are given by (Subscript[Y, ℓ]^m)(θ,ϕ)=(Sqrt[(((2 ℓ+l))/(4 π))(((ℓ-|m|)!)/((ℓ+|m|)!))])(Subscript[P, ℓ]^(|m|))(cosθ)(e^(i m ϕ)), where (Subscript[P, ℓ]^m) are associated Legendre polynomials and l and m are the orbital and magnetic quantum numbers, respectively. The allowed values of the quantum numbers, which follow from the boundary conditions of the problem, are ℓ=0,1,2,... ,∞, m=0,±1,±2,...,±ℓ.  The complex function (Subscript[Y, ℓ]^m)(θ,ϕ) is shown on the left, where the shape is its modulus and the coloring corresponds to its argument, the range 0 to 2π corresponding to colors from red to magenta. The center and right graphics show the corresponding real and imaginary parts.

DETAILS

S. M. Blinder, Introduction to Quantum Mechanics: In Chemistry, Materials Science and Biology, Burlington, MA: Elsevier Academic Press, 2004.

THIS NOTEBOOK IS THE SOURCE CODE FROM

"Complex Spherical Harmonics" from the Wolfram Demonstrations Project
 http://demonstrations.wolfram.com/ComplexSphericalHarmonics/

Contributed by: Porscha McRobbie and Eitan Geva

A full-function Wolfram Mathematica system (Version 6 or higher) is required to edit this notebook.
GET WOLFRAM MATHEMATICA »

© Wolfram Demonstrations Project & Contributors   |   Terms of Use   |   Make a new version of this Demonstration »